Solución de ecuaciones lineales en Maxima

Ecuaciones lineales

Para resolver una ecuación se usa la instrucción $solve(ecuacion,variable)$. Donde $variable$ es con respecto a la cual se va a resolver la ecuación.

Ejemplos de solución de una ecuación lineal

(%i1)

solve(2*x+3=4*x-5,x);

\[\mathrm{\tt (\%o1) }\quad [x=4]\]

(%i2)

/*Se resuelve la ecuación con respecto a x*/ solve(2*x-2*a=4*x-5,x);

\[\mathrm{\tt (\%o2) }\quad [x=-\frac{2\cdot a-5}{2}]\]

(%i3)

/*Se resuelve la ecuación con respecto a la variable a*/ solve(2*x-2*a=4*x-5,a);

\[\mathrm{\tt (\%o3) }\quad [a=-\frac{2\cdot x-5}{2}]\]

---

Created with wxMaxima.

Máximos y mínimos de una función

Valores máximos y mínimos de una función

Ejemplo.

Determinar los intervalos de crecimiento y de decrecimiento, identificar los puntos críticos y determinar los valores máximos y mínimos de la función $f\left(x\right)=4\,x^3+3\,x^2-6\,x$

(%i85)

f(x):=4*x**3+3*x**2-6*x;

\[\mathrm{\tt (\%o85) }\quad \mathrm{f}\left( x\right) :=4\cdot {{x}^{3}}+3\cdot {{x}^{2}}-6\cdot x\]

Intervalos de crecimiento. Los intervalos en los cuáles ${{d\,f\left(x\right)}\over{d\,x}}>0$

(%i86)

load(solve_rat_ineq);

\[\mathrm{\tt (\%o86) }\quad C:/Program\,Files/Maxima-gcl-5.37.3/share/maxima/5.37.3/share/solve\_rat\_ineq/solve\_rat\_ineq.mac\]

(%i87)

solve_rat_ineq(diff(f(x),x)>0);

\[\mathrm{\tt (\%o87) }\quad [[x<-1],[x>\frac{1}{2}]]\]

Intervalos de decrecimiento. Los intervalos en los cuáles ${{d\,f\left(x\right)}\over{d\,x}}<0$

(%i88)

solve_rat_ineq(diff(f(x),x)<0);

\[\mathrm{\tt (\%o88) }\quad [[x>-1,x<\frac{1}{2}]]\]

Valores críticos. Los valores de $x$ para los cuales ${{d\,f\left(x\right)}\over{d\,x}}=0$

(%i89)

vc0:solve(diff(f(x),x)=0);

\[\mathrm{\tt (\%o89) }\quad [x=\frac{1}{2},x=-1]\]

Considerando el criterio de la primera derivada, se puede concluir que en $x=-1$ hay un valor máximo de $f(x)$; en $x={{1}\over{2}}$ hay un valor mínimo de $f(x)$.

El valor mínimo es

(%i90)

f(rhs(vc0[1]));

\[\mathrm{\tt (\%o90) }\quad -\frac{7}{4}\]

El valor máximo es

(%i91)

f(rhs(vc0[2]));

\[\mathrm{\tt (\%o91) }\quad 5\]

Utilizando el criterio de la segunda derivada,

La segunda derivada de la función es

(%i92)

'diff('f(x),x,2)=diff(f(x),x,2);

\[\mathrm{\tt (\%o92) }\quad \frac{{{d}^{2}}}{d\,{{x}^{2}}}\cdot \mathrm{f}\left( x\right) =24\cdot x+6\]

Se evalúa la segunda derivada en cada valor crítico

En

(%i93)

vc0[1];

\[\mathrm{\tt (\%o93) }\quad x=\frac{1}{2}\]

la segunda derivada es

(%i94)

at(diff(f(x),x,2),vc0[1]);

\[\mathrm{\tt (\%o94) }\quad 18\]

por lo tanto en $x={{1}\over{2}}$ hay un valor mínimo

En

(%i95)

vc0[2];

\[\mathrm{\tt (\%o95) }\quad x=-1\]

vale

(%i96)

at(diff(f(x),x,2),vc0[2]);

\[\mathrm{\tt (\%o96) }\quad -18\]

por lo tanto en $x=-1$ hay un valor máximo

Segunda Derivada

Segunda derivada

(%i81)

f(x):=(x**2+5)**3;

\[\mathrm{\tt (\%o81) }\quad \mathrm{f}\left( x\right) :={{\left( {{x}^{2}}+5\right) }^{3}}\]

(%i82)

'diff('f(x),x,2)=diff(f(x),x,2);

\[\mathrm{\tt (\%o82) }\quad \frac{{{d}^{2}}}{d\,{{x}^{2}}}\cdot \mathrm{f}\left( x\right) =6\cdot {{\left( {{x}^{2}}+5\right) }^{2}}+24\cdot {{x}^{2}}\cdot \left( {{x}^{2}}+5\right) \]

se puede simplificar agregando $ratsimp$

(%i83)

'diff('f(x),x,2)=diff(f(x),x,2),ratsimp;

\[\mathrm{\tt (\%o83) }\quad \frac{{{d}^{2}}}{d\,{{x}^{2}}}\cdot \mathrm{f}\left( x\right) =30\cdot {{x}^{4}}+180\cdot {{x}^{2}}+150\]

Tercera derivada

(%i84)

'diff('f(x),x,3)=diff(f(x),x,3),ratsimp;

\[\mathrm{\tt (\%o84) }\quad \frac{{{d}^{3}}}{d\,{{x}^{3}}}\cdot \mathrm{f}\left( x\right) =120\cdot {{x}^{3}}+360\cdot x\]

Derivación implícita en Maxima

Derivación implícita

Ejemplo

Calcular ${{d\,y}\over{d\,x}}$ para $y^2-x\,y+x^3=4$

Para derivar implícitamente en maxima se hace lo siguiente

Se indica que la variable $y$ es función de $x$

(%i75)

depends(y,x);

\[\mathrm{\tt (\%o75) }\quad [\mathrm{y}\left( x\right) ]\]

Se ingresa la ecuación

(%i76)

ec0:x**3-x*y+y**2=4;

\[\mathrm{\tt (\%o76) }\quad {{y}^{2}}-x\cdot y+{{x}^{3}}=4\]

Se obtiene la derivada con respecto a la variable $x$

(%i77)

ec1:diff(ec0,x);

\[\mathrm{\tt (\%o77) }\quad 2\cdot y\cdot \left( \frac{d}{d\,x}\cdot y\right) -x\cdot \left( \frac{d}{d\,x}\cdot y\right) -y+3\cdot {{x}^{2}}=0\]

Se resuelve la ecuación anterior con respecto a ${{d\,y}\over{d\,x}}$

(%i78)

solve(ec1,'diff(y,x));

\[\mathrm{\tt (\%o78) }\quad [\frac{d}{d\,x}\cdot y=\frac{y-3\cdot {{x}^{2}}}{2\cdot y-x}]\]

El resultado anterior esta en formato de lista, si se desea extraer el único elemento de esa lista, la derivada, se agrega $[1]$ al final de la instrucción anterior

(%i79)

solve(ec1,'diff(y,x))[1];

\[\mathrm{\tt (\%o79) }\quad \frac{d}{d\,x}\cdot y=\frac{y-3\cdot {{x}^{2}}}{2\cdot y-x}\]

Para borrar la dependencia de $y$ de $x$

(%i80)

remove(y, dependency);

\[\mathrm{\tt (\%o80) }\quad \mathit{done}\]

Derivada de una función

Derivada de una función

La instrucción para calcular la derivada de una función con respecto a una variable es $diff(funcion,variable)$

Ejemplo

Calcular la derivada de la función $$f\left(x\right)=3\,x^2-2\,x-1$$

(%i70)

f(x):=3*x**2-2*x-1;

\[\mathrm{\tt (\%o70) }\quad \mathrm{f}\left( x\right) :=3\cdot {{x}^{2}}-2\cdot x-1\]

(%i71)

diff(f(x),x);

\[\mathrm{\tt (\%o71) }\quad 6\cdot x-2\]

Otra forma de presentar el resultado es el siguiente utilizando el operador comilla simple

(%i72)

'diff('f(x),x)=diff(f(x),x);

\[\mathrm{\tt (\%o72) }\quad \frac{d}{d\,x}\cdot \mathrm{f}\left( x\right) =6\cdot x-2\]

Ejemplo

Calcular la derivada de la función $$f\left(x\right)=\sin \sqrt{x^3+3\,x}$$

(%i73)

f(x):=sin(sqrt(x**3+3*x));

\[\mathrm{\tt (\%o73) }\quad \mathrm{f}\left( x\right) :=\mathrm{sin}\left( \sqrt{{{x}^{3}}+3\cdot x}\right) \]

(%i74)

'diff('f(x),x)=diff(f(x),x);

\[\mathrm{\tt (\%o74) }\quad \frac{d}{d\,x}\cdot \mathrm{f}\left( x\right) =\frac{\left( 3\cdot {{x}^{2}}+3\right) \cdot \mathrm{cos}\left( \sqrt{{{x}^{3}}+3\cdot x}\right) }{2\cdot \sqrt{{{x}^{3}}+3\cdot x}}\]

Continuidad de una función

3 Continuidad de una función

Ejemplo. Determinar si la función $$f\left(x\right)=x^2-1$$ es continua en el punto $a=2$

(%i67)

f(x):=x**2-1;

\[\mathrm{\tt (\%o67) }\quad \mathrm{f}\left( x\right) :={{x}^{2}}-1\]

Directamente se puede determinar la continuidad con la siguiente instrucción

(%i68)

is(limit(f(x),x,2)=f(2));

\[\mathrm{\tt (\%o68) }\quad \mbox{true}\]

Ejemplo. Determinar si la función $$f\left(x\right)={{x^3-8}\over{x-2}}$$ es continua en el punto $a=2$

(%i69)

f(x):=(x**3-8)/(x-2);

\[\mathrm{\tt (\%o69) }\quad \mathrm{f}\left( x\right) :=\frac{{{x}^{3}}-8}{x-2}\]

Directamente se puede determinar la continuidad con la siguiente instrucción $$is(limit(f(x),x,2)=f(2));$$ En este caso, al ejecutarla, aparece un mensaje de error, dado que la función no está definida en $x=2$.

Si se muestra un error indica que la función no está definida en el punto dado. Por lo tanto la función no es continua en ese valor.

Límite lateral de una función

Ejemplo. Límites laterales

Límite por la derecha

Calcular el límite por la derecha $$\lim_{x\downarrow 2}{5-x^2}$$

(%i61)

f(x):=5-x**2;

\[\mathrm{\tt (\%o61) }\quad \mathrm{f}\left( x\right) :=5-{{x}^{2}}\]

Una forma

(%i62)

limit(f(x),x,2,plus);

\[\mathrm{\tt (\%o62) }\quad 1\]

Otra forma

(%i63)

'limit(f(x),x,2,plus)=limit(f(x),x,2,plus);

\[\mathrm{\tt (\%o63) }\quad \lim_{x\to 2+}{5-{{x}^{2}}}=1\]

Límite por la izquierda

Calcular el límite por la izquierda $$\lim_{x\uparrow 2}{2\,x-3}$$

(%i64)

f(x):=2*x-3;

\[\mathrm{\tt (\%o64) }\quad \mathrm{f}\left( x\right) :=2\cdot x-3\]

Una forma

(%i65)

limit(f(x),x,2,minus);

\[\mathrm{\tt (\%o65) }\quad 1\]

Otra forma

(%i66)

'limit(f(x),x,2,minus)=limit(f(x),x,2,minus);

\[\mathrm{\tt (\%o66) }\quad \lim_{x\to 2-}{2\cdot x-3}=1\]